# # ## ### ##### ######## ############# #####################
## API - Start interception and saving.

proc ::famfamfam::subset::new {name version dst} {
    # Create a package NAME + VERSION with saved icons at the given
    # location.

    variable destination
    variable pkg_name
    variable pkg_version


    if {$destination ne {}} {
        return -code error "Assembly in progress, unable to start a second"
    }

    set destination $dst
    set pkg_name $name
    set pkg_version $version

    # Create the directory we will collect the images in.
    file mkdir $destination
    
    # Generate administrative files only if they do not exist.
    # They will be updated later if icons are added.
    if {![file exists $destination/pkgIndex.tcl] || \
        ![file exists $destination/loader.tcl] || \
        ![file exists $destination/teapot.txt]} {
        GeneratePackageFiles
    }

    # At last tell the core to report to us which images are loaded so
    # that we can record them into the package we are creating.
    famfamfam intercept ::famfamfam::subset::save
    return
}
proc ::famfamfam::subset::GeneratePackageFiles {} {
    # Generate (updated) administrative files.
    variable destination
    variable pkg_name
    variable pkg_version
    variable ptemplate
    variable ttemplate
    variable template

    lappend map @@name@@    $pkg_name
    lappend map @@qname@@   [list $pkg_name]
    lappend map @@version@@ $pkg_version
    lappend map @@time@@    [clock format [clock seconds]]
    lappend map @@qtime@@   [list [clock format [clock seconds]]]
    lappend map @@user@@    $::tcl_platform(user)

    # Generate a package index ...
    set    c [open $destination/pkgIndex.tcl w]
    puts  $c [string map $map $ptemplate]
    close $c

    # ... And the package code
    set    c [open $destination/loader.tcl w]
    puts  $c [string map $map $template]
    close $c

    # Generate a teapot.txt ...
    set    c [open $destination/teapot.txt w]
    puts  $c [string map $map $ttemplate]
    close $c




    return
}

proc ::famfamfam::subset::save {iconset iconname iconpath} {
    variable destination

    if {$destination eq {}} {
        return -code error "No assembly in progress."
    }
    
    # Check if the image is really new
    set oldiconpath [file join $destination/icons/$iconset [file tail $iconpath]]
    if {[file exists $oldiconpath]} {
        set fp [open $iconpath r]
        fconfigure $fp -translation binary
        set new [read $fp]
        close $fp
        set fp [open $oldiconpath r]
        fconfigure $fp -translation binary
        set old [read $fp]
        close $fp
    } else {
        # make them different by default
        set old old
        set new new
    }

    # Record the image into the package we are assembling.
    # Only if not already there or different.
    # Update package files also.
    if {$old ne $new} {
        file mkdir $destination/icons/$iconset
        file copy -force -- $iconpath $destination/icons/$iconset/
        GeneratePackageFiles
    }
    return
}

proc ::famfamfam::subset::done {} {
    # Stop recording.
    variable destination

    namespace export {[a-z]*}
    namespace ensemble create
}

# # ## ### ##### ######## ############# #####################
## Ready

package provide famfamfam::subset 1.1
return

# # ## ### ##### ######## ############# #####################
# Local variables:
# mode: tcl
# indent-tabs-mode: nil
# End: