#!/usr/bin/env tclsh
#
# Monitor the database file named by the DBFILE variable
# looking for email messages sent by Fossil.  Forward each
# to /usr/sbin/sendmail.
#

set PIPE "sendmail -ti"
set MAINDB "/home/chiselapp/mail.db"

package require sqlite3

proc uuid {} {
	return [exec uuidgen -r]
}

proc log {level message} {
	catch {
		set fd [open /var/log/fossil-send-mail.log a+]
		puts $fd "[clock format [clock seconds]] $level $message"
	}
	catch {
		close $fd
	}
}

proc debug_log {msg} {
	log debug $msg
}

proc error_log {msg} {
	log error $msg
}

proc process_user_file {dbfile user maindb} {
	sqlite3 db $dbfile

	set added_rows [list]
	try {
		db timeout 60000
		catch {
			db eval {PRAGMA journal_mode=WAL}
		}

		db transaction immediate {
			set to_delete [list]
			db eval {SELECT emailid, msg FROM email} row {
				set emailid [uuid]
				set msg $row(msg)

				debug_log "Copying $user:$row(emailid) -> maindb:$emailid"
				$maindb eval {INSERT INTO email (emailid, user, msg, sent) VALUES ($emailid, $user, $msg, 0);}

				lappend to_delete $row(emailid)
				lappend added_rows $emailid
			}

			foreach emailid $to_delete {
				db eval {DELETE FROM email WHERE emailid = $emailid}
			}
		}
	} on error {} {
		foreach emailid $added_rows {
			$maindb eval {DELETE FROM email WHERE emailid = $emailid}
		}
	} finally {
		db close
	}
}

proc sanitize_message {msg} {
	set msg [regsub -all -line {^From: .*$} $msg "From: ChiselApp.com <noreply@chiselapp.com>"]
	return $msg
}

proc process_file {maindb} {
	set to_mark_error [list]
	set to_delete [list]

	try {
		$maindb transaction immediate {
			$maindb eval {SELECT emailid, user, msg FROM email WHERE sent = 0} row {
				debug_log "Processing $row(emailid):$row(user)..."

				set msg [sanitize_message $row(msg)]

				lappend to_delete $row(emailid)

				if {[catch {
					set out [open |$::PIPE w]
					puts -nonewline $out $msg
					close $out
				} err]} {
					error_log "Error: $err $row(user):$row(emailid)"

					lappend to_mark_error $row(emailid) $err
				}
			}
		}
	} finally {
		$maindb transaction immediate {
			foreach {emailid err} $to_mark_error {
				$maindb eval {UPDATE email SET send_error = $err WHERE emailid = $emailid}
			}

			foreach {emailid} $to_delete {
				$maindb eval {UPDATE email SET sent = 1 WHERE emailid = $emailid}
			}
		}
	}
}

proc main {} {
	sqlite3 maindb $::MAINDB
	maindb timeout 60000
	maindb eval {CREATE TABLE IF NOT EXISTS email (emailid PRIMARY KEY, user NOT NULL, msg NOT NULL, send_error, sent BOOLEAN NOT NULL)}
	maindb eval {CREATE INDEX IF NOT EXISTS emailBySent ON email (sent)}
	catch {
		maindb eval {PRAGMA journal_mode=WAL}
	}

	while 1 {
		maindb transaction {
			foreach dbfile [glob -nocomplain /home/chiselapp/www/repos/*/data/mail.sql] {
				set user [lindex [split $dbfile /] end-2]

				if {[catch {
					process_user_file $dbfile $user maindb
				} err]} {
					error_Log "Error processing $dbfile: $err"
				}
			}
		}

		catch {
			process_file maindb
		}

		after 10000
	}
}

main