#
# $Id: configure.in,v 1.11 2004/03/09 19:54:31 jenglish Exp $
#
builtin(include, ../tclconfig/tcl.m4)
AC_REVISION($Revision: 1.11 $)
AC_INIT(tile.c)
AC_CONFIG_AUX_DIR(../tclconfig)
AC_DEFUN([AC_LIBOBJ],[])
# Package identification:
#
PACKAGE_NAME=tile
MAJOR_VERSION=0
MINOR_VERSION=3
PATCHLEVEL=
VERSION=${MAJOR_VERSION}.${MINOR_VERSION}
AC_SUBST(PACKAGE)
AC_SUBST(VERSION)
AC_SUBST(PATCHLEVEL)
# Usual Tcl stuff:
#
TEA_INIT([3.0])
TEA_PATH_TCLCONFIG
TEA_LOAD_TCLCONFIG
# Usual Tk stuff:
#
TEA_PATH_TKCONFIG
TEA_LOAD_TKCONFIG
TEA_PREFIX
dnl
dnl Alternative to TEA_SETUP_COMPILER:
dnl (TEA_SETUP_COMPILER is for building Tcl itself)
dnl
AC_PROG_CC
AC_PROG_INSTALL
AC_OBJEXT
AC_EXEEXT
dnl
TEA_PUBLIC_TCL_HEADERS
TEA_PUBLIC_TK_HEADERS
AC_DEFINE(NO_PRIVATE_HEADERS)
TEA_PROG_WISH
# Build stuff:
#
TEA_CONFIG_CFLAGS
TEA_PATH_X
TEA_ENABLE_THREADS
TEA_ENABLE_SHARED
TEA_ENABLE_SYMBOLS
AC_DEFINE(USE_TCL_STUBS)
AC_DEFINE(USE_TK_STUBS)
# Don't use: `TEA_MAKE_LIB', it's on crack.
# This is the only bit we need:
#
CFLAGS="${CFLAGS} ${CFLAGS_DEFAULT} \$(CFLAGS_WARNING)"
if test "${SHARED_BUILD}" = "1" ; then
CFLAGS="${CFLAGS} \$(SHLIB_CFLAGS)"
fi
# Platform-specific stuff:
#
if test "${TEA_PLATFORM}" = "windows" ; then
PLATFORM_OBJS='$(WIN_OBJS)'
PKG_LIBS="${PKG_LIBS} user32.lib"
# @@@ OR: -luser32, if using GCC
elif test "${OSTYPE}" = "darwin" ; then
AC_DEFINE(MAC_OSX_TK)
PLATFORM_OBJS='$(MAC_OBJS)'
#@@@ At this point PKG_LIBS contains "-lX11".
#@@@ We don't want that, so replace instead of extending.
PKG_LIBS="-framework Carbon"
else
PLATFORM_OBJS='$(X11_OBJS)'
fi
AC_SUBST(PLATFORM_OBJS)
#--------------------------------------------------------------------
# Same test as in tcl.m4 for MSVC "link" vs. ld/cc/etc.
if test "${TEA_PLATFORM}" = "windows" -a "$GCC" != "yes"; then
SHLIB_LD_OUT="/out:"
else
SHLIB_LD_OUT="-o "
fi
AC_SUBST(SHLIB_LD_OUT)
AC_SUBST(SHLIB_SUFFIX)
AC_OUTPUT([Makefile pkgIndex.tcl])
#*EOF*