Artifact 073a72e2812dfc99280a63d0e1c01212441c29ff:

• File support.tcl — part of check-in [89cea61f4a] at 2012-03-22 17:29:14 on branch trunk — Extended the set of scale operators to the greyN types, and exposed them through a new public method (crimp scale). Updated documentation. Regenerated embedded documentation. Tweaked the output generated by critcl a bit (feedback while reading .crimp files). (user: andreask size: 1114) [more...]

# -*- tcl -*-
# CRIMP Build Support Code
#
# (c) 2011 Andreas Kupries http://wiki.tcl.tk/andreas%20kupries

# # ## ### ##### ######## #############

## Code factored out of the main crimp_xxx.tcl files

# # ## ### ##### ######## #############

proc crimp_source_cproc {accept {reject {}}} {
    set here [file dirname [file normalize [info script]]]

    foreach pa $accept {
	foreach filename [lsort -dict [glob -nocomplain -tails -directory $here $pa]] {
	    set take 1
	    foreach pr $reject {
		if {![string match $pr $filename]} continue
		set take 0
		break
	    }
	    if {!$take} continue

	    #critcl::msg -nonewline " \[[file rootname [file tail $filename]]\]"
	    critcl::msg -nonewline .

	    set chan [open $here/$filename r]
	    set name ::crimp::[gets $chan]
	    set params "Tcl_Interp* interp"
	    set number 2
	    while {1} {
		incr number
		set line [gets $chan]
		if {$line eq ""} {
		    break
		}
		append params " $line"
	    }
	    set body "\n#line $number \"[file tail $filename]\"\n[read $chan]"
	    close $chan
	    ::critcl::cproc $name $params ok $body
	}
    }
    return
}