; GIMP - The GNU Image Manipulation Program
; Copyright (C) 1995 Spencer Kimball and Peter Mattis
;
; This program is free software: you can redistribute it and/or modify
; it under the terms of the GNU General Public License as published by
; the Free Software Foundation; either version 3 of the License, or
; (at your option) any later version.
;
; This program is distributed in the hope that it will be useful,
; but WITHOUT ANY WARRANTY; without even the implied warranty of
; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
; GNU General Public License for more details.
;
; You should have received a copy of the GNU General Public License
; along with this program.  If not, see <http://www.gnu.org/licenses/>.

; Allow command line usage of GIMP such as:
; 
;     gimp -i -b '(with-files "*.png" <body>)'
; 
; where <body> is the code that handles whatever processing you want to 
; perform on the files. There are four variables that are available within
; the <body>: 'filename', 'basename', 'image', and 'layer'. The 'filename'
; is the full path of the original file. The 'basename' is the 
; name of the file with its extension removed, while the other two 
; variables are self-explanatory. You basically write your code as though 
; it were processing a single 'image' and the 'with-files' macro applies 
; it to all of the files matching the pattern.
; 
; For example, to invert the colors of all of the PNG files in the 
; start directory:
;    
;    gimp -i -b '(with-files "*.png" \
;                  (gimp-invert layer) \
;                  (gimp-file-save 1 image layer filename filename))'

(define-macro (with-files pattern . body)
  (let ((loop (gensym))
        (filenames (gensym)))
    `(begin
       (let ,loop ((,filenames (cadr (file-glob ,pattern 1))))
         (unless (null? ,filenames)
           (let* ((filename (car ,filenames))
                  (image (catch #f (car (gimp-file-load RUN-NONINTERACTIVE
                                                        filename 
                                                        filename ))))
                  (layer (if image (car (gimp-image-get-active-layer image)) #f))
                  (basename (catch filename 
				   (unbreakupstr (butlast (strbreakup filename ".")) "."))))
             (when image
               ,@body
               (gimp-image-delete image)))
           (,loop (cdr ,filenames))))
       (gimp-quit 0))))
