#!/usr/bin/gawk -f
#
# Demonstration on how to create a GTK GUI using psalm with Gnu AWK.
#
#  Run as follows using socat:
#   socat EXEC:./psalm EXEC:./demo.awk
#
#  Or with dpipe from VDE2:
#   dpipe ./psalm = ./demo.awk
#
# Or using pipexec:
#   pipexec [ A ./psalm ] [ B ./demo.awk ] "{A:1>B:0}" "{B:1>A:0}"
#
# Or native Linux:
#   : | { ./psalm | ./demo.awk; } > /dev/fd/0
#
# November 18, 2022 by Peter van Eerten.
#------------------------------------------------

function comm(str)
{
    print str
    fflush()
    getline
    return $0
}

BEGIN{
    # Send definitions first
    comm("DEF libgtk-3.so.0 void gtk_init int int")
    comm("DEF libgtk-3.so.0 long gtk_window_new int")
    comm("DEF libgtk-3.so.0 void gtk_window_set_title int char*")
    comm("DEF libgtk-3.so.0 void gtk_widget_set_size_request long int int")
    comm("DEF libgtk-3.so.0 void gtk_window_set_position long int")
    comm("DEF libgtk-3.so.0 long gtk_table_new int int int")
    comm("DEF libgtk-3.so.0 void gtk_container_add long long")
    comm("DEF libgtk-3.so.0 long gtk_button_new_with_label char*")
    comm("DEF libgtk-3.so.0 long gtk_entry_new void")
    comm("DEF libgtk-3.so.0 char* gtk_entry_get_text long")
    comm("DEF libgtk-3.so.0 long gtk_label_new void")
    comm("DEF libgtk-3.so.0 void gtk_label_set_text long char*")
    comm("DEF libgtk-3.so.0 void gtk_table_attach_defaults long long int int int int")
    comm("DEF libgtk-3.so.0 void gtk_widget_show_all int")
    comm("DEF libgobject-2.0.so.0 long g_signal_connect_data int char* address void* void* int")
    comm("DEF libgtk-3.so.0 void gtk_main_iteration void")

    # Design GUI
    comm("EXE gtk_init NULL NULL")
    win = comm("EXE gtk_window_new 0")
    comm("EXE gtk_window_set_title " win " \"This is a title\"")
    comm("EXE gtk_window_set_position " win " 1")
    table = comm("EXE gtk_table_new 30 30 1")
    comm("EXE gtk_container_add " win " " table)
    but1 = comm("EXE gtk_button_new_with_label Exit")
    comm("EXE gtk_table_attach_defaults " table " " but1 " 17 28 20 25")
    but2 = comm("EXE gtk_button_new_with_label \"Print text\"")
    comm("EXE gtk_table_attach_defaults " table " " but2 " 2 13 20 25")
    entry = comm("EXE gtk_entry_new")
    comm("EXE gtk_table_attach_defaults " table " " entry " 2 28 5 10")
    label = comm("EXE gtk_label_new")
    comm("EXE gtk_table_attach_defaults " table " " label " 2 28 12 17")
    comm("EXE gtk_label_set_text " label " \"<Text appears here>\"")
    comm("EXE gtk_widget_show_all " win)

    # Connect signals
    comm("EXE g_signal_connect_data " win " delete-event callback NULL NULL 0")
    comm("EXE g_signal_connect_data " but1 " clicked callback NULL NULL 0")
    comm("EXE g_signal_connect_data " but2 " clicked callback NULL NULL 0")

    # Mainloop
    do {
        comm("EXE gtk_main_iteration")
        cb = comm("CALLBACK 1")
        if (cb == but2)
        {
            txt = comm("EXE gtk_entry_get_text " entry)
            comm("EXE gtk_label_set_text " label " "txt)
        }
    } while(cb != but1 && cb != win)

    comm("EXIT")
}

Return to PSALM